Interactive Time Scrubber

Let's keep on the subject "How to turn Max into Motionbuilder"!
While working with Motionbuilder, I got accustomed to use the Time Scrubbing by holding down the J key and dragging left or right in the viewport. It allows to easily see what's in between the keyframes, which can be very useful, especially for video games animation!

 --------------------------------------------------------  
 --Time Scrubber-----------------------------------------  
 --Vincent Schneider 2015--------------------------------  
 --------------------------------------------------------  
 macroScript timeScrub  
 ButtonText:"Time Scrub"  
 category:"Vin"   
 internalcategory:"Vin"  
 (  
      if timeScrub != undefined then  
      (  
           startTool timeScrub  
      )  
      else  
      (  
           tool timeScrub  
           (  
                local baseMousePos = mouse.screenpos.x  
                local previousMousePos  
                local deadZone = 1  
                local precision = 32  
                on mousePoint clickno do  
                (  
                     if clickno == 1 then  
                     (  
                          frameRate *= precision  
                          baseMousePos = mouse.screenpos.x  
                          setSysCur #move  
                     )  
                     else  
                     (  
                          frameRate /= precision  
                          #stop  
                     )  
                )  
                  
                on mouseMove clickno do  
                (  
                     setSysCur #move  
                     do  
                     (  
                          mouseX = mouse.screenpos.x  
                          mouseDelta = baseMousePos - mouseX  
                          if abs mouseDelta > deadZone then  
                          (  
                               sliderTime -= ceil(mouseDelta*0.1)  
                          )  
                          sleep 0.001  
                     )  
                     while previousMousePos == mouseX  
                     previousMousePos = mouseX  
                )  
           )  
           startTool timeScrub  
      )  
 )  

Once you have assigned this tool to a shortcut, here's how to use it:
Start the tool with the assigned shortcut, then click and hold anywhere in the viewport and move your cursor left or right to scrub precisely.

You can now keep a close eye on every last bits of your animations !

You can find the macroScript here and instructions on how to use them here !